! ANSYS柱子稳定分析算例
! Example of geometry nonlinear analysis in ANSYS
! 要点:预应力,特征值屈曲,添加初始缺陷,几何非线性分析
! 作者: 陆新征,清华大学土木系
! Author: Lu Xinzheng Dept. Civil Engrg. of Tsinghua University
! last revised: 2003.2.
!
finish
/CLEAR
/UNITS,SI
/PREP7
!*
FORCE=100
OFFSET=0.1 !初始缺陷为0.1

! 建立模型

ET,1,BEAM4
ET,2,LINK10
R,1,0.1*0.12,0.12*0.1**3/12,0.1*0.12**3/12,0.12,0.1, ,
R,2,0.002*0.002,2e-3, !预应力
MPTEMP,1,0
MPDATA,EX,1,,200e9
MPDATA,PRXY,1,,0.27
MPDATA,DENS,1,,7800
k,1,
k,2,0,0,5
k,3,0,0,-5
k,11,0.2,0,0
k,12,-0.2,0,0
k,13,0,0.2
k,15,0,-0.2
l,1,2
l,1,3
l,1,11
l,1,12
l,1,13
l,1,15
l,2,11
l,2,12
l,2,13
l,2,15
l,3,11
l,3,12
l,3,13
l,3,15
lsel,,,,1,6
latt,1,1,1
ALLSEL,ALL
lsel,,,,7,14
latt,1,2,2
ALLSEL,ALL
lsel,,,,1,6
LESIZE,all,0.3, , , , , , ,1
lsel,,,,7,14
LESIZE,all, , ,1 , , , , ,1
ALLSEL,ALL
LMESH,ALL
FINISH
/ESHAPE,1.0
!*
! 求解特征值屈曲荷载

*DO,I,1,100
FINISH
/SOLU
DK,3, , , ,0,UX,UY,UZ, , ,ROTZ ,
DK,2, , , ,0,UX,UY, , , , ,
FK,2,FZ,-FORCE

ANTYPE,0
!设定时间步
TIME,1
AUTOTS,0
NSUBST,1, , ,1
!NLGEOM,1
SSTIF,ON

SOLVE
FINISH
/SOLU
ANTYPE,BUCKLE ! Buckling analysis
BUCOPT,LANB,1 ! Use Block Lanczos solution method, extract 1 mode
MXPAND,1 ! Expand 1 mode shape

PSTRES,ON ! INCLUDE PRESTRESS EFFECTS
SOLVE
FINISH

*GET,FREQ1,MODE,1,FREQ
*IF,FREQ1,LT,0.01,THEN
FREQ1=0.01
*ENDIF
*IF,ABS(FREQ1-1),LT,0.01,THEN !如果频率误差小于1%
*EXIT
*ENDIF
FORCE=FORCE*FREQ1
*ENDDO

! 添加初始缺陷
FINISH
/POST1
SET,FIRST
NSORT,U,SUM
*GET,DMAX,SORT, ,MAX
!*
FINISH
/prep7
upgeom,OFFSET/DMAX,1,1,beammodel,rst

! 非线性求解
FINISH
/SOLU
!*
FORCE=FORCE*3.
DK,3, , , ,0,UX,UY,UZ, , ,ROTZ ,
DK,2, , , ,0,UX,UY, , , , ,
FK,2,FZ,-FORCE
ANTYPE,0
NLGEOM,1
NSUBST,20,0,0
OUTRES,ALL,1
ARCLEN,1,0,0
AUTOTS,-1.0
SOLVE

! 绘制荷载位移曲线
FINISH
/POST26
FILE
FILE,'beammodel','rst','.'
/UI,COLL,1
NUMVAR,200
FILLDATA,191,,,,1,1
REALVAR,191,191
NUMVAR,200
FILLDATA,191,,,,1,1
REALVAR,191,191
!*
NSOL,2,2,U,Z, UZ_2
STORE,MERGE
!*
RFORCE,3,19,F,Z, FZ_3
STORE,MERGE
XVAR,2
PLVAR,3,

个人信息
研究工作
实际工程
论文工作
教学工作
资料下载
专题
其他

我们的实验室

抗倒塌专业委员会