! 用ANSYS Solid 65单元分析约束混凝土圆柱轴压问题的简单例子
! 给出建模和计算的基本过程
! 作者:陆新征,清华大学土木工程系
! 说明:
! 根据清华大学FRP研究组2000年~2001年的研究分析,
! ANSYS的混凝土材性本构模型在分析高轴压问题时表现一般,
! 对分析结果不必给予太高期望。目前无论是在国际上还是在
! 清华,对FRP约束混凝土的认识和分析工作已经比2001年要
! 发展了很多。因此,本命令流仅作为教学和一般性工程研究参
! 考,已经不代表当前清华对该问题的认识水平。请在使用时
! 注意这点。
!
! Simulate the concrete column confined with FRP tube
! with Solid 65 element in ANSYS
! Author: Lu Xinzheng, Dept. Civil Engrg. of Tsinghua University
! Note:
! The following file is the work done by Tsinghua University in
! 2000~2001. Our current research has obtained a lot pf progress
! since that time. Hence, the following file is not present our
! current research level. Only for the educational purpose.


/PREP7
!*
! FRP 厚度, FRP thickness
thick=0.11
! 混凝土弹模, Concrete Elastic Modulus
Ec=30e3
! 混凝土泊松比, Concrete Poisson ratio
EMUc=0.2
! 混凝土抗压抗拉强度
! Concrete Compressive and Tensile Strength
fc=30
ft=3
! FRP弹模和泊松比
! Elastic Modulue and Poisson ratio for FRP
Ef=230e3
EMUf=0.3
! Height and Radius of Tube
! 圆柱高度和半径
H=450
R=150
! Maximal axial strain
! 最大试验轴向应变
EPSMax=0.006

! 选择混凝土单元, Concrete element

ET,1,SOLID65
!*
KEYOPT,1,1,0
KEYOPT,1,5,0
KEYOPT,1,6,0
KEYOPT,1,7,1
!*
! 选择FRP单元, FRP element
ET,2,SHELL41
!*
KEYOPT,2,1,2
KEYOPT,2,2,0
KEYOPT,2,4,0
KEYOPT,2,5,0
KEYOPT,2,6,0
!*
! 设定混凝土单单元实参数
! Concrete element real constants
R,1,2, , , ,2, ,
RMORE, , ,2, , , ,
! 设定FRP单元实参数
! FRP element real constants
R,2,thick,thick,thick,thick, , ,
RMORE, ,
!*
! 输入混凝土材料, Concrete material parameters
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,Ec
MPDATA,PRXY,1,,EMUc
!
! 输入应力应变曲线, Concrete stress-stain curve
TB,MISO,1,1,5,
TBTEMP,0
TBPT,,0.0005,fc*0.5
TBPT,,0.001,fc*0.7
TBPT,,0.0015,fc*0.85
TBPT,,0.002,fc
TBPT,,0.003,fc*0.8
!
! 输入破坏曲面, Failure envelop surface
TB,CONC,1,1,9,
TBTEMP,0
TBDATA,,.5,.9,ft,-1,,
TBDATA,,,,1,,,
MPTEMP,,,,,,,,
MPTEMP,1,0
!
! 输入FRP材料参数, FRP material parameters
MPDATA,EX,2,,Ef
MPDATA,PRXY,2,,EMUf
! 建立圆柱模型, Tube model
CYL4,0,0,R, , , ,H

! 取1/4截面, a quarter of section
wpro,,-90.000000,
VSBW, 1
WPCSYS,-1
wpro,, ,-90.000000,
VSBW,ALL
WPCSYS,-1
VSEL,S, , , 4,6,1,
VDELE,ALL, , ,1
ALLSEL,ALL
NUMCMP,AREA

! 赋予材性, assign material property
VATT, 1, 1, 1, 0
ASEL,S , , ,3,
AATT, 2, 2, 2, 0,

! 划分单元网格,mesh
ESIZE,R/3,0,
VSEL, , , , 1
VMESH,1
MSHAPE,0,2D
MSHKEY,0
ASEL,S , , ,3,
AMESH,ALL
!*
ALLSEL,ALL
FINISH
/SOLU
!*
ANTYPE,0
!*
CNVTOL,U, ,0.02,0, ,
!*
NSUBST,30,0,10
CUTCONTROL,NOITERPRED,1
DA,2,UZ,
! 最大压缩量, maximal axial displacement
DA,1,UZ,H*EPSMax
DA,4,UY,
DA,5,UX,
DK,9, , , ,0,ALL, , , , , ,
DK,1, , , ,0,UX, , , , , ,
OUTRES,ALL,1

SAVE
SOLVE
FINISH

个人信息
研究工作
实际工程
论文工作
教学工作
资料下载
专题
其他


我们的实验室