!* 利用ANSYS计算土壤中管道温度应力
!* Example for thermal stress of a pipe inside soil with ANSYS
! 作者:陆新征,清华大学土木工程系
! Author: Lu Xinzheng Dept. Civil Engrg. of Tsinghua University
!* Feb, 15, 2006
!*

*SET,R1,5 ! 内径大小
*SET,R2,6 ! 外径大小
*SET,L,20 ! 土体计算范围
/prep7
!* 生成关键点模型
k,1001,0,0,
k,1,0,R1,
k,2,0,-R1
k,3,R1,0
k,4,0,-R2
k,5,R2,
k,6,0,R2
k,7,0,-L
k,8,L,-L
k,9,l,0
k,10,L,l
k,11,0,L

!* 生成线段
l,1,6
larc,1,3,1001,R1
larc,3,2,1001,R1
l,2,4
larc,5,4,1001,R2
larc,6,5,1001,R2
l,3,5
l,4,7
l,7,8
l,8,9
l,5,9
l,9,10
l,10,11
l,6,11

al,3,4,5,7
al,1,2,7,6
al,8,9,10,11,5
al,11,12,13,14,6

ET,1,PLANE42
!*
!* 混凝土材料
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,30e9
MPDATA,PRXY,1,,0.2
MPTEMP,,,,,,,,
MPTEMP,1,0
UIMP,1,REFT,,,
MPDATA,ALPX,1,,1e-5 ! 热膨胀系数
!* 土壤材料
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,2,,30e6
MPDATA,PRXY,2,,0.2

!* 设定材料属性
asel,s,,,1,2,
AATT, 1, , 1, 0,
asel,s,,,3,4,
AATT, 2, , 1, 0,
ALLSEL,ALL

!* 设定单元尺寸
ESIZE,R2/6,0,
MSHAPE,0,2D
MSHKEY,0
!* 划分网格
amesh,all

FINISH
/SOL
!* 静力分析
ANTYPE,0
!* 对称边界条件
lsel,s,,,1,
lsel,a,,,4,
lsel,a,,,8,
lsel,a,,,14,
nsll,s,1
d,all,UX,0
!* 四周土体约束
lsel,s,,,9,10,
lsel,a,,,12,
nsll,s,1
d,all,all,
lsel,s,,,2,3
nsll,s,1
!* 在管道内表面施加温度荷载200摄氏度
BF,ALL,TEMP,200
!* 建立所有属于管道单元的节点选择集
allsel,all
asel,s,,,1,2
nsla,s,1
cm,N_Area,Node
!* 建立所有管道外表面节点选择集
lsel,s,,,1,6,
nsll,s,1
cm,N_Line,Node
!* 将管道中所有节点排除表面节点得到管道的内部节点
cmsel,s,N_Area,Node
cmsel,u,N_Line,Node
!* 在所有内部节点上时间100摄氏度的温度荷载
BF,all,TEMP,100
allsel,all
!* 求解
solve
!*
FINISH
/POST1
!* 得到管道及周围土体变形图
SET,LAST
PLDISP,2
/AUTO, 1
/REP

个人信息
研究工作
实际工程
论文工作
教学工作
资料下载
专题
其他

我们的实验室